wh9 k线策略模型:基于均线与动能的交易系统策略公式 [复制链接]

    autojiaoyi.com 发表于 ・1272 次阅读 库安 wh9 查看全部 使用道具 举报 回复

    wh9 k线策略模型:基于均线与动能的交易系统策略公式

    Params
       Numeric FastMALength(5); //动能计算中的快均线周期
       Numeric SlowMALength(20); //动能计算中的慢均线周期
       Numeric TrendMALength(50); //趋势线计算中的周期数
       Numeric ExitStopN(3); //求高低点的bar数值   
    Vars
       NumericSeries TrendMA; //趋势线
       NumericSeries PriceOsci; //均线动能
       NumericSeries ExitL; //多头出场价格
       NumericSeries ExitS; //空头出场价格
       NumericSeries MP; //MarketPosition状态记录
       Numeric N; //下单手数
       Numeric SH; //平仓参数
       Numeric RLP,FLP; //涨跌停价
       Numeric BIDP,ASKP; //买卖一价
       Numeric BRP,SRP; //多空头可用持仓
       Numeric OPFLG; //模型处理标志
       Numeric BKDFLG; //买开处理标志
       Numeric SKDFLG; //卖开处理标志
       Numeric BPDFLG; //买平处理标志
       Numeric SPDFLG; //卖平处理标志
       Global_Numeric BKID,SKID; //开仓委托
       Global_Numeric BPID,SPID; //平仓委托
       Global_Numeric BKFLG,SKFLG; //开仓标志
       Global_Numeric BPFLG,SPFLG; //平仓标志
       Global_Numeric BKM,SKM; //开仓委托手数
       Global_Numeric BPM,SPM; //平仓委托手数
       Global_Numeric BKP,SKP; //开仓委托价格
       Global_Numeric BPP,SPP; //平仓委托价格
    Begin
       //------------------------信号发出------------------------//
       If(1) //信号发出
       {
          TrendMA = AverageFC(Close,TrendMALength); //计算TrendMALength周期收盘价的平均值
          PriceOsci = PriceOscillator(Close,FastMALength,SlowMALength); //计算FastMALength,SlowMALength周期收盘价的快慢周期震荡值
          ExitL = LLV(Low,ExitStopN); //计算ExitStopN周期内最低价的最小值
          ExitS = HHV(High,ExitStopN); //计算ExitStopN周期内最高价的最大值
          PlotNumeric("TrendMA",TrendMA); //输出趋势线
          PlotNumeric("PriceOsci",PriceOsci); //输出均线动能
          //多头入场
          If(MarketPosition <> 1 && TrendMA[1] <> 0) //无多头持仓且上根趋势线不等于0
          {
             //上根K线的收盘价高于上根的趋势线,上根K线的动能相对于上上根为增强且动能为负
             If(Close[1] > TrendMA[1] && PriceOsci[1] <= 0 && PriceOsci[1] > PriceOsci[2] && Vol > 0)
             {
                BK(DefaultVol,Open); //以开盘价做多
             }
          }
          //空头入场
          If(MarketPosition <> -1 && TrendMA[1] <> 0) //无空头持仓且上根趋势线不等于0
          {
             //上根K线的收盘价低于上根的趋势线,上根K线的动能相对于上上根为减弱且动能为正
             If(Close[1] < TrendMA[1] && PriceOsci[1] >= 0 && PriceOsci[1] < PriceOsci[2] && Vol > 0)
             {
                SK(DefaultVol,Open); //以开盘价做空
             }
          }
          //多头出场
          If(MarketPosition == 1 && MP[1] == 1) //持有多仓
          {
             //上根K线的动能相对于上上根为减弱,价格跌破多头出场价,成交量大于0
             If(PriceOsci[1] < PriceOsci[2] && Low <= ExitL[1] && Vol > 0)
             {
                SP(DefaultVol,Min(Open,ExitL[1])); //以开盘价与上根ExitL的较小值平多
             }
          }
          MP = MarketPosition;
          //空头出场
          If(MarketPosition == -1 && MP[1] == -1) //持有空仓
          {
             //上根K线的动能相对于上上根为增强,价格突破空头出场价,成交量大于0
             If(PriceOsci[1] > PriceOsci[2] && High >= ExitS[1] && Vol > 0)
             {
                BP(DefaultVol,Max(Open,ExitS[1])); //以开盘价与上根ExitS的较大值平空
             }
          }
          MP = MarketPosition;
       }
       //------------------------处理开启------------------------//
       If(A_IsExchangeOpen() == 1) //如果是开盘状态
       {
          If(BarStatus() == 2) //如果不带入历史值
          {
             If(RunStart() == 1) //如果已初始化成功
             {
                OPFLG = 1; //开启模型处理
             }
          }
       }
       //------------------------变量赋值------------------------//
       If(OPFLG == 1) //变量赋值
       {
          N = 1; //下单手数
          BIDP = Price("Bid1"); //买一价
          ASKP = Price("Ask1"); //卖一价
          RLP = Price("RiseLimit"); //涨停价
          FLP = Price("FallLimit"); //跌停价
          BRP = F_BuyRemainPosition(); //多头可用持仓
          SRP = F_SellRemainPosition(); //空头可用持仓
          BRP = Min(BRP,A_BuyRemainPosition()); //多头可用持仓
          SRP = Min(SRP,A_SellRemainPosition()); //空头可用持仓
          If(A_IsSHCode() == 1) //如果是上期所合约
          {
             SH = Enum_ExitToday; //平仓参数
          }
          Else //如果非上期所合约
          {
             SH = Enum_Exit; //平仓参数
          }
       }
       //------------------------信号处理------------------------//
       If(OPFLG == 1) //信号处理
       {
          If(F_FreshSig() == 1) //如果当前信号是未处理过的信号
          {
             If(F_SigValid() == 1) //如果当前信号未消失
             {
                If(F_Sig() == Sig_BK) //如果信号类型为BK
                {
                   Commentary("【BK信号!】");
                   BKDFLG = 1; //开启买开处理
                }
                Else If(F_Sig() == Sig_SP) //如果信号类型为SP
                {
                   Commentary("【SP信号!】");
                   SPDFLG = 1; //开启卖平处理
                }
                Else If(F_Sig() == Sig_SK) //如果信号类型为SK
                {
                   Commentary("【SK信号!】");
                   SKDFLG = 1; //开启卖开处理
                }
                Else If(F_Sig() == Sig_BP) //如果信号类型为BP
                {
                   Commentary("【BP信号!】");
                   BPDFLG = 1; //开启买平处理
                }
             }
          }
       }
       //------------------------成交判断------------------------//
       If(OPFLG == 1) //成交判断
       {
          If(BKFLG == 1) //如果有买开委托
          {
             If(F_OrderStatus(BKID) == Enum_Filled) //如果买开委托成交
             {
                Commentary("【BK信号:买开委托成交!】");
                BKFLG = 0; //买开标志归0
             }
          }
          If(SPFLG == 1) //如果有卖平委托
          {
             If(F_OrderStatus(SPID) == Enum_Filled) //如果卖平委托成交
             {
                Commentary("【SP信号:卖平委托成交!】");
                SPFLG = 0; //卖平标志归0
             }
          }
          If(SKFLG == 1) //如果有卖开委托
          {
             If(F_OrderStatus(SKID) == Enum_Filled) //如果卖开委托成交
             {
                Commentary("【SK信号:卖开委托成交!】");
                SKFLG = 0; //卖开标志归0
             }
          }
          If(BPFLG == 1) //如果有买平委托
          {
             If(F_OrderStatus(BPID) == Enum_Filled) //如果买平委托成交
             {
                Commentary("【BP信号:买平委托成交!】");
                BPFLG = 0; //买平标志归0
             }
          }
       }
       //------------------------委托处理------------------------//
       If(OPFLG == 1) //委托处理
       {
          If(BKDFLG == 1) //如果已开启买开处理
          {
             If(BKFLG == 0) //如果没有买开委托
             {
                BKM = N; //买开委托手数
                BKP = ASKP; //买开委托价格
                Commentary("【BK信号:买开委托发出!】");
                BKID = A_SendOrder(Enum_Buy,Enum_Entry,BKM,BKP); //发出买开委托
                BKFLG = 1; //已发出买开委托
             }
          }
          If(SPDFLG == 1) //如果已开启卖平处理
          {
             If(SPFLG == 0) //如果没有卖平委托
             {
                If(BRP > 0) //如果有多头可用持仓
                {
                   SPM = BRP; //卖平委托手数
                   SPP = FLP; //卖平委托价格
                   Commentary("【SP信号:卖平委托发出!】");
                   SPID = A_SendOrder(Enum_Sell,SH,SPM,SPP); //发出卖平委托
                   SPFLG = 1; //已发出卖平委托
                }
             }
          }
          If(SKDFLG == 1) //如果已开启卖开处理
          {
             If(SKFLG == 0) //如果没有卖开委托
             {
                SKM = N; //卖开委托手数
                SKP = BIDP; //卖开委托价格
                Commentary("【SK信号:卖开委托发出!】");
                SKID = A_SendOrder(Enum_Sell,Enum_Entry,SKM,SKP); //发出卖开委托
                SKFLG = 1; //已发出卖开委托
             }
          }
          If(BPDFLG == 1) //如果已开启买平处理
          {
             If(BPFLG == 0) //如果没有买平委托
             {
                If(SRP > 0) //如果有空头可用持仓
                {
                   BPM = SRP; //买平委托手数
                   BPP = RLP; //买平委托价格
                   Commentary("【BP信号:买平委托发出!】");
                   BPID = A_SendOrder(Enum_Buy,SH,BPM,BPP); //发出买平委托
                   BPFLG = 1; //已发出买平委托
                }
             }
          }
       }
    End
    热帖

    全部评论/0 条

    本版积分规则

    发布新内容
    加入收藏 我要分享
    分享到论坛或者博客

    复制
    热门指标策略
    快速回复 返回顶部 返回列表