wh9 k线策略模型:基于市场强弱与动量突破系统策略公式 [复制链接]

    autojiaoyi.com 发表于 ・814 次阅读 库安 wh9 查看全部 使用道具 举报 回复

    wh9 k线策略模型:基于市场强弱与动量突破系统策略公式

    Params
       Numeric Length(5); //强弱指标和通道计算的周期值
       Numeric Stop_Len(5); //止损通道的周期值
       Numeric ProfitFactor(3); //止盈相对止损的倍数
       Numeric EntryStrength(95); //强弱指标的进场值
    Vars
       Numeric X; //循环控制变量
       Numeric UpCloses; //收盘价上涨累计值
       Numeric DnCloses; //收盘价下跌累计值
       Numeric SumChange; //收盘价变动累计值
       NumericSeries CloseChange; //收盘价变动值
       NumericSeries MarketStrength; //市场强弱指标
       NumericSeries Momentum1; //当前Bar相对前4根BAR的动量
       NumericSeries Momentum2; //前4根BAR相对前8根BAR的动量
       NumericSeries HH; //N周期高点 
       NumericSeries HH1; //N周期高点 
       NumericSeries HH2; //N周期高点 
       NumericSeries LL; //N周期低点
       NumericSeries LL1; //N周期低点
       NumericSeries LL2; //N周期低点
       NumericSeries StopLoss; //止损位
       NumericSeries ProfitTarget; //止盈位
       Numeric N; //下单手数
       Numeric SH; //平仓参数
       Numeric RLP,FLP; //涨跌停价
       Numeric BIDP,ASKP; //买卖一价
       Numeric BRP,SRP; //多空头可用持仓
       Numeric OPFLG; //模型处理标志
       Numeric BKDFLG; //买开处理标志
       Numeric SKDFLG; //卖开处理标志
       Numeric BPDFLG; //买平处理标志
       Numeric SPDFLG; //卖平处理标志
       Global_Numeric BKID,SKID; //开仓委托
       Global_Numeric BPID,SPID; //平仓委托
       Global_Numeric BKFLG,SKFLG; //开仓标志
       Global_Numeric BPFLG,SPFLG; //平仓标志
       Global_Numeric BKM,SKM; //开仓委托手数
       Global_Numeric BPM,SPM; //平仓委托手数
       Global_Numeric BKP,SKP; //开仓委托价格
       Global_Numeric BPP,SPP; //平仓委托价格
    Begin
       //------------------------信号发出------------------------//
       If(1) //信号发出
       {
          //计算市场强弱指标
          CloseChange = Close - Close[1];
          UpCloses = 0;
          DnCloses = 0;
          For X = 0 To Length - 1
          {
             //收盘价上涨计入涨幅累计
             If(CloseChange[X] > 0)
             {
                UpCloses = UpCloses + CloseChange[X];
             }
             //否则计入跌幅累计
             Else
             {
                DnCloses = DnCloses + CloseChange[X];
             }
          }
          //计算周期内涨跌
          SumChange = Sum(CloseChange,Length);
          //周期内上涨,计算上涨强度,0-100之间
          If(SumChange >= 0)
          {
             MarketStrength = SumChange / UpCloses * 100;
          }
          //周期内下跌,计算下跌强度,0-100之间
          Else
          {
             MarketStrength = SumChange / Abs(DnCloses) * 100;
          }
          //计算动量
          Momentum1 = Close - Close[4];
          Momentum2 = Close[4] - Close[8];
          //计算周期高低点,多头开仓突破用
          HH = HHV(High,Length); //最高价
          LL1 = LLV(Low,Length); //最低价
          //计算周期高低点,空头开仓突破用
          HH1 = HHV(High,Length); //最高价
          LL = LLV(Low,Length); //最低价
          //计算周期低点,多头开仓后止损用
          LL2 = LLV(Low,Stop_Len);
          //计算周期高点,空头开仓后止损用
          HH2 = HHV(High,Stop_Len);
          //多头开仓条件
          If(MarketPosition == 0 && MarketStrength[1] >= EntryStrength && Momentum1[1] >= 0 && Momentum2[1] < 0 && High >= HH[1] && Vol > 0)
          {
             BK(DefaultVol,Max(Open,HH[1]));
             //记录开仓BAR的周期低点作为止损位
             StopLoss = LL2;
             //根据止损位计算止盈位
             ProfitTarget = EntryPrice + (EntryPrice - StopLoss) * ProfitFactor;
          }
          //空头开仓条件
          If(MarketPosition == 0 && MarketStrength[1] <= -1 * EntryStrength && Momentum1[1] <= 0 && Momentum2[1] > 0 && Low <= LL[1] && Vol > 0)
          {
             SK(DefaultVol,Min(Open,LL[1]));
             //记录开仓BAR的周期高点作为止损位
             StopLoss = HH2;
             //根据止损位计算止盈位
             ProfitTarget = EntryPrice - (StopLoss - EntryPrice) * ProfitFactor;
          }
          //多头平仓条件
          If(MarketPosition == 1 && BarsSinceEntry > 0 && Vol > 0)
          {
             If(High >= ProfitTarget) //最高价>=止盈价
             {
                SP(DefaultVol,Max(Open,ProfitTarget));
             }
             Else If(Low <= StopLoss) //最低价<=止损价
             {
                SP(DefaultVol,Min(Open,StopLoss));
             }
             Else If(MarketStrength[1] <= -1 * EntryStrength && Momentum1[1] < 0 && Momentum2[1] >= 0 && Low <= LL1[1])
             {
                SP(DefaultVol,Min(Open,LL1[1]));
             }
          }
          //空头平仓条件
          If(MarketPosition == -1 && BarsSinceEntry > 0 && Vol > 0)
          {
             If(Low <= ProfitTarget) //最低价<=止盈价位
             {
                BP(DefaultVol,Min(Open,ProfitTarget));
             }
             Else If(High >= StopLoss) //最高价>=止损价位
             {
                BP(DefaultVol,Max(Open,StopLoss));
             }
             Else If(MarketStrength[1] >= EntryStrength && Momentum1[1] > 0 && Momentum2[1] <= 0 && High >= HH1[1])
             {
                BP(DefaultVol,Max(Open,HH1[1]));
             }
          }
       }
       //------------------------处理开启------------------------//
       If(A_IsExchangeOpen() == 1) //如果是开盘状态
       {
          If(BarStatus() == 2) //如果不带入历史值
          {
             If(RunStart() == 1) //如果已初始化成功
             {
                OPFLG = 1; //开启模型处理
             }
          }
       }
       //------------------------变量赋值------------------------//
       If(OPFLG == 1) //变量赋值
       {
          N = 1; //下单手数
          BIDP = Price("Bid1"); //买一价
          ASKP = Price("Ask1"); //卖一价
          RLP = Price("RiseLimit"); //涨停价
          FLP = Price("FallLimit"); //跌停价
          BRP = F_BuyRemainPosition(); //多头可用持仓
          SRP = F_SellRemainPosition(); //空头可用持仓
          BRP = Min(BRP,A_BuyRemainPosition()); //多头可用持仓
          SRP = Min(SRP,A_SellRemainPosition()); //空头可用持仓
          If(A_IsSHCode() == 1) //如果是上期所合约
          {
             SH = Enum_ExitToday; //平仓参数
          }
          Else //如果非上期所合约
          {
             SH = Enum_Exit; //平仓参数
          }
       }
       //------------------------信号处理------------------------//
       If(OPFLG == 1) //信号处理
       {
          If(F_FreshSig() == 1) //如果当前信号是未处理过的信号
          {
             If(F_SigValid() == 1) //如果当前信号未消失
             {
                If(F_Sig() == Sig_BK) //如果信号类型为BK
                {
                   Commentary("【BK信号!】");
                   BKDFLG = 1; //开启买开处理
                }
                Else If(F_Sig() == Sig_SP) //如果信号类型为SP
                {
                   Commentary("【SP信号!】");
                   SPDFLG = 1; //开启卖平处理
                }
                Else If(F_Sig() == Sig_SK) //如果信号类型为SK
                {
                   Commentary("【SK信号!】");
                   SKDFLG = 1; //开启卖开处理
                }
                Else If(F_Sig() == Sig_BP) //如果信号类型为BP
                {
                   Commentary("【BP信号!】");
                   BPDFLG = 1; //开启买平处理
                }
             }
          }
       }
       //------------------------成交判断------------------------//
       If(OPFLG == 1) //成交判断
       {
          If(BKFLG == 1) //如果有买开委托
          {
             If(F_OrderStatus(BKID) == Enum_Filled) //如果买开委托成交
             {
                Commentary("【BK信号:买开委托成交!】");
                BKFLG = 0; //买开标志归0
             }
          }
          If(SPFLG == 1) //如果有卖平委托
          {
             If(F_OrderStatus(SPID) == Enum_Filled) //如果卖平委托成交
             {
                Commentary("【SP信号:卖平委托成交!】");
                SPFLG = 0; //卖平标志归0
             }
          }
          If(SKFLG == 1) //如果有卖开委托
          {
             If(F_OrderStatus(SKID) == Enum_Filled) //如果卖开委托成交
             {
                Commentary("【SK信号:卖开委托成交!】");
                SKFLG = 0; //卖开标志归0
             }
          }
          If(BPFLG == 1) //如果有买平委托
          {
             If(F_OrderStatus(BPID) == Enum_Filled) //如果买平委托成交
             {
                Commentary("【BP信号:买平委托成交!】");
                BPFLG = 0; //买平标志归0
             }
          }
       }
       //------------------------委托处理------------------------//
       If(OPFLG == 1) //委托处理
       {
          If(BKDFLG == 1) //如果已开启买开处理
          {
             If(BKFLG == 0) //如果没有买开委托
             {
                BKM = N; //买开委托手数
                BKP = ASKP; //买开委托价格
                Commentary("【BK信号:买开委托发出!】");
                BKID = A_SendOrder(Enum_Buy,Enum_Entry,BKM,BKP); //发出买开委托
                BKFLG = 1; //已发出买开委托
             }
          }
          If(SPDFLG == 1) //如果已开启卖平处理
          {
             If(SPFLG == 0) //如果没有卖平委托
             {
                If(BRP > 0) //如果有多头可用持仓
                {
                   SPM = BRP; //卖平委托手数
                   SPP = FLP; //卖平委托价格
                   Commentary("【SP信号:卖平委托发出!】");
                   SPID = A_SendOrder(Enum_Sell,SH,SPM,SPP); //发出卖平委托
                   SPFLG = 1; //已发出卖平委托
                }
             }
          }
          If(SKDFLG == 1) //如果已开启卖开处理
          {
             If(SKFLG == 0) //如果没有卖开委托
             {
                SKM = N; //卖开委托手数
                SKP = BIDP; //卖开委托价格
                Commentary("【SK信号:卖开委托发出!】");
                SKID = A_SendOrder(Enum_Sell,Enum_Entry,SKM,SKP); //发出卖开委托
                SKFLG = 1; //已发出卖开委托
             }
          }
          If(BPDFLG == 1) //如果已开启买平处理
          {
             If(BPFLG == 0) //如果没有买平委托
             {
                If(SRP > 0) //如果有空头可用持仓
                {
                   BPM = SRP; //买平委托手数
                   BPP = RLP; //买平委托价格
                   Commentary("【BP信号:买平委托发出!】");
                   BPID = A_SendOrder(Enum_Buy,SH,BPM,BPP); //发出买平委托
                   BPFLG = 1; //已发出买平委托
                }
             }
          }
       }
    End
    热帖

    全部评论/0 条

    本版积分规则

    发布新内容
    加入收藏 我要分享
    分享到论坛或者博客

    复制
    热门指标策略
    快速回复 返回顶部 返回列表