wh9 k线策略模型:基于肯纳德通道的交易系统策略公式 [复制链接]

    autojiaoyi.com 发表于 ・504 次阅读 库安 wh9 查看全部 使用道具 举报 回复

    wh9 k线策略模型:基于肯纳德通道的交易系统策略公式

    策略公式源码如下:
    Params
       Numeric Length(10); //均线参数
       Numeric Constt(12); //通道倍数
       Numeric ChanPcnt(5); //入场参数
       Numeric BuyN(5); //多头入场触发条件有效K线周期
       Numeric SellN(5); //空头入场触发条件有效K线周期
       Numeric StopN(4); //低点止损参数
    Vars
       NumericSeries TPrice; //关键价格
       NumericSeries KCU; //通道上轨
       NumericSeries KCL; //通道下轨
       NumericSeries ChanRng; //通道宽度
       NumericSeries AvgVal; //通道中轨
       NumericSeries AvgRange; //真实波动均值(ATR)
       NumericSeries Setbar;
       NumericSeries Setbar1;
       NumericSeries CountL; //触发单周期变量
       NumericSeries CountS; //触发单周期变量 
       NumericSeries HH; //多头触发单价位
       NumericSeries LL; //空头触发单价位
       NumericSeries LStopLine; //止损线
       NumericSeries SStopLine; //止损线
       NumericSeries Con;
       NumericSeries Con2;
       Numeric N; //下单手数
       Numeric SH; //平仓参数
       Numeric RLP,FLP; //涨跌停价
       Numeric BIDP,ASKP; //买卖一价
       Numeric BRP,SRP; //多空头可用持仓
       Numeric OPFLG; //模型处理标志
       Numeric BKDFLG; //买开处理标志
       Numeric SKDFLG; //卖开处理标志
       Numeric BPDFLG; //买平处理标志
       Numeric SPDFLG; //卖平处理标志
       Global_Numeric BKID,SKID; //开仓委托
       Global_Numeric BPID,SPID; //平仓委托
       Global_Numeric BKFLG,SKFLG; //开仓标志
       Global_Numeric BPFLG,SPFLG; //平仓标志
       Global_Numeric BKM,SKM; //开仓委托手数
       Global_Numeric BPM,SPM; //平仓委托手数
       Global_Numeric BKP,SKP; //开仓委托价格
       Global_Numeric BPP,SPP; //平仓委托价格
    Begin
       //------------------------信号发出------------------------//
       If(1) //信号发出
       {
          //指标计算
          TPrice = Close; //关键价格,可以换成中位价等
          AvgVal = Ma(TPrice,Length); //计算均线 默认10周期
          AvgRange = Ma(TrueRange,Length); //计算真实波动均值(ATR)默认10周期
          KCU = AvgVal + AvgRange * Constt / 10; //计算通道上轨=均线+1.2倍的10周期真实波动值
          KCL = AvgVal - AvgRange * Constt / 10; //计算通道下轨=均线-1.2倍的10周期真实波动值
          ChanRng = (KCU - KCL) / 2; //通道宽度/2      
          CountL = CountL + 1; //每经过1根K线CountL+1,用于判断信号取消的变量,上穿上轨后,默认参数:开仓点仅挂单5根K线
          CountS = CountS + 1; //每经过1根K线CountL+1,用于判断信号取消的变量,下穿下轨后,默认参数:开仓点仅挂单5根K线
          Con = CrossUp(TPrice,KCU); //bool变量con,当价格上穿上轨时为真   
          If(Con == 1)
          {
             SetBar = High;
             CountL = 0;
             HH = SetBar + (ChanRng * ChanPcnt / 10); //当con为真时,计算开仓线hh,CountL重置为0
             SetBar1 = Low;
             CountS = 0;
             LL = SetBar - (ChanRng * ChanPcnt / 10);
          }
          //多头系统入场
          //当价格上穿上轨,且在BuyN根K线内>=HH时,买入开仓
          If(MarketPosition == 0)
          {
             If(TPrice[1] > KCU[1] && CountL <= BuyN && High >= HH)
             {
                BK(DefaultVol,Max(Open,HH));
             }
          }
          //空头系统入场
          //当价格下穿下轨,且在SellN根K线内<LL时,卖出开仓
          If(MarketPosition == 0)
          {
             If(TPrice[1] < KCL[1] && CountS <= SellN && Low <= LL)
             {
                SK(DefaultVol,Min(Open,LL));
             }
          }
          //多头系统出场
          Con2 = CrossDown(Close,AvgVal); //bool变量con,当价格下穿轨道中轨时为真
          LStopLine = LLV(Low[1],StopN);
          If(MarketPosition == 1 && BarsSinceEntry > 0)
          {
             //价格下穿轨道中轨时平仓
             If(Con2[1] == 1)
             {
                SP(DefaultVol,Open);
             }
             //价格小于N周期低点平仓
             If(Low <= LStopLine)
             {
                SP(DefaultVol,Min(Open,LStopLine));
             }
          }
          //空头系统出场
          Con2 = CrossUp(Close,AvgVal); //bool变量con,当价格上穿轨道中轨时为真
          SStopLine = HHV(High[1],StopN);
          If(MarketPosition == -1 && BarsSinceEntry > 0)
          {
             //价格上穿轨道中轨时平仓
             If(Con2[1] == 1)
             {
                BP(DefaultVol,Open);
             }
             //价格大于N周期高点平仓
             If(High >= SStopLine)
             {
                BP(DefaultVol,Max(SStopLine,Open));
             }
          }
       }
       //------------------------处理开启------------------------//
       If(A_IsExchangeOpen() == 1) //如果是开盘状态
       {
          If(BarStatus() == 2) //如果不带入历史值
          {
             If(RunStart() == 1) //如果已初始化成功
             {
                OPFLG = 1; //开启模型处理
             }
          }
       }
       //------------------------变量赋值------------------------//
       If(OPFLG == 1) //变量赋值
       {
          N = 1; //下单手数
          BIDP = Price("Bid1"); //买一价
          ASKP = Price("Ask1"); //卖一价
          RLP = Price("RiseLimit"); //涨停价
          FLP = Price("FallLimit"); //跌停价
          BRP = F_BuyRemainPosition(); //多头可用持仓
          SRP = F_SellRemainPosition(); //空头可用持仓
          BRP = Min(BRP,A_BuyRemainPosition()); //多头可用持仓
          SRP = Min(SRP,A_SellRemainPosition()); //空头可用持仓
          If(A_IsSHCode() == 1) //如果是上期所合约
          {
             SH = Enum_ExitToday; //平仓参数
          }
          Else //如果非上期所合约
          {
             SH = Enum_Exit; //平仓参数
          }
       }
       //------------------------信号处理------------------------//
       If(OPFLG == 1) //信号处理
       {
          If(F_FreshSig() == 1) //如果当前信号是未处理过的信号
          {
             If(F_SigValid() == 1) //如果当前信号未消失
             {
                If(F_Sig() == Sig_BK) //如果信号类型为BK
                {
                   Commentary("【BK信号!】");
                   BKDFLG = 1; //开启买开处理
                }
                Else If(F_Sig() == Sig_SP) //如果信号类型为SP
                {
                   Commentary("【SP信号!】");
                   SPDFLG = 1; //开启卖平处理
                }
                Else If(F_Sig() == Sig_SK) //如果信号类型为SK
                {
                   Commentary("【SK信号!】");
                   SKDFLG = 1; //开启卖开处理
                }
                Else If(F_Sig() == Sig_BP) //如果信号类型为BP
                {
                   Commentary("【BP信号!】");
                   BPDFLG = 1; //开启买平处理
                }
             }
          }
       }
       //------------------------成交判断------------------------//
       If(OPFLG == 1) //成交判断
       {
          If(BKFLG == 1) //如果有买开委托
          {
             If(F_OrderStatus(BKID) == Enum_Filled) //如果买开委托成交
             {
                Commentary("【BK信号:买开委托成交!】");
                BKFLG = 0; //买开标志归0
             }
          }
          If(SPFLG == 1) //如果有卖平委托
          {
             If(F_OrderStatus(SPID) == Enum_Filled) //如果卖平委托成交
             {
                Commentary("【SP信号:卖平委托成交!】");
                SPFLG = 0; //卖平标志归0
             }
          }
          If(SKFLG == 1) //如果有卖开委托
          {
             If(F_OrderStatus(SKID) == Enum_Filled) //如果卖开委托成交
             {
                Commentary("【SK信号:卖开委托成交!】");
                SKFLG = 0; //卖开标志归0
             }
          }
          If(BPFLG == 1) //如果有买平委托
          {
             If(F_OrderStatus(BPID) == Enum_Filled) //如果买平委托成交
             {
                Commentary("【BP信号:买平委托成交!】");
                BPFLG = 0; //买平标志归0
             }
          }
       }
       //------------------------委托处理------------------------//
       If(OPFLG == 1) //委托处理
       {
          If(BKDFLG == 1) //如果已开启买开处理
          {
             If(BKFLG == 0) //如果没有买开委托
             {
                BKM = N; //买开委托手数
                BKP = ASKP; //买开委托价格
                Commentary("【BK信号:买开委托发出!】");
                BKID = A_SendOrder(Enum_Buy,Enum_Entry,BKM,BKP); //发出买开委托
                BKFLG = 1; //已发出买开委托
             }
          }
          If(SPDFLG == 1) //如果已开启卖平处理
          {
             If(SPFLG == 0) //如果没有卖平委托
             {
                If(BRP > 0) //如果有多头可用持仓
                {
                   SPM = BRP; //卖平委托手数
                   SPP = FLP; //卖平委托价格
                   Commentary("【SP信号:卖平委托发出!】");
                   SPID = A_SendOrder(Enum_Sell,SH,SPM,SPP); //发出卖平委托
                   SPFLG = 1; //已发出卖平委托
                }
             }
          }
          If(SKDFLG == 1) //如果已开启卖开处理
          {
             If(SKFLG == 0) //如果没有卖开委托
             {
                SKM = N; //卖开委托手数
                SKP = BIDP; //卖开委托价格
                Commentary("【SK信号:卖开委托发出!】");
                SKID = A_SendOrder(Enum_Sell,Enum_Entry,SKM,SKP); //发出卖开委托
                SKFLG = 1; //已发出卖开委托
             }
          }
          If(BPDFLG == 1) //如果已开启买平处理
          {
             If(BPFLG == 0) //如果没有买平委托
             {
                If(SRP > 0) //如果有空头可用持仓
                {
                   BPM = SRP; //买平委托手数
                   BPP = RLP; //买平委托价格
                   Commentary("【BP信号:买平委托发出!】");
                   BPID = A_SendOrder(Enum_Buy,SH,BPM,BPP); //发出买平委托
                   BPFLG = 1; //已发出买平委托
                }
             }
          }
       }
    End
    热帖

    全部评论/0 条

    本版积分规则

    发布新内容
    加入收藏 我要分享
    分享到论坛或者博客

    复制
    热门指标策略
    快速回复 返回顶部 返回列表